装备或更换双手武器宏
#showtooltip 野蛮角斗士的碾骨锤
/stopcasting
/equipslot 16 野蛮角斗士的碾骨锤
---第一行为宏的图标,#showtooltip 后面的武器改成野蛮角斗士的墙盾就显示盾牌的图标,但不影响下面宏的作用
---第二行的作用是停止预读的攻击,如英勇,顺劈,这些技能是预读占用下一次平砍攻击的,有的战士在PK的时候换武器或盾会死死卡住什么也动不了,就是因为你预读了一个英勇打击,如果这个英勇打不出去你是绝对换不了装备的,尤其在对法师的时候,想盾反,却因为距离不够英勇没打出去而卡住换不了盾,这时如果加入stopcasting取消这个预读的英勇,你就可以自由换武器盾牌了,下面的盾反宏同理.
---第三行的作用是装备指定武器到指定位置,16为主手位置,17为副手位置,这种换装备的宏在现在的版本对狂暴战是必不可少的
狂暴战装备两把双手
#showtooltip 野蛮角斗士的碾骨锤
/stopcasting
/equipslot 16 野蛮角斗士的碾骨锤
/equipslot 17 复仇角斗士的碾骨锤
换盾宏
#showtooltip 野蛮角斗士的墙盾
/stopcasting
/equipslot 16 残酷角斗士的轻锤
/equipslot 17 野蛮角斗士的墙盾
---还是用了equipslot,如果是狂暴战,你可以把主手换成双手武器,同样stopcasting在换武器的时候必加,就是为了防止卡在英勇打击那里
援护宏
#showtooltip 援护
/cast [target=砸你娃头,modifier:alt,nodead,exists,help]援护;[target=mouseover,nodead,exists,help][target=target,nodead,exists][target=targettarget,nodead,exists] 援护
---我的宏技术含量很低,但是很实用,这个援护宏是我经过无数次实践更改得出来的,最满意的一个,网上有很多援护宏,但基本都有不合适的地方,我这个是集多种功能与一身的(再次炫耀...)
---首先[target=砸你娃头,modifier:alt,nodead,exists,help]援护这一段是当你按住alt键施放援护就援护指定的角色:砸你娃头,如果没有按住alt则此条不执行
---进入下一条[target=mouseover,nodead,exists,help]作用是援护你鼠标指定的目标,如果目标死亡,不存在,敌对就不执行此条
---下一条[target=target,nodead,exists]援护目标为你当前目标,这个跟你不用宏施放援护的作用一样
---下一条[target=targettarget,nodead,exists]援护目标为目标的目标,作用也跟你不用宏一样
---总的来说好像很没必要,但如果集成mouseover,这个宏做不好就要出很多问题,这个宏最终的作用是优先援护指定目标就援护指定的目标,其次援护你鼠标指向的目标就援护鼠标指向,再次直接就能援护目标
射击宏绑定猛击
#showtooltip [equipped:投掷武器] 投掷;射击
/cast [equipped:投掷武器] 投掷; 射击
/equip [equipped:弓/弩]永恒箭矢; [equipped:枪械] 永恒弹丸
/cast 猛击
---前段时间玩了会狂暴战,总感觉技能快捷键用不过来了,就把猛击绑定到射击宏里,近身就猛击,远离就射击,我的目的是为狂暴天赋里血涌的顺发猛击
拦截宏
#showtooltip 拦截
/target mouseover,nodead,exists,harm
/cast 拦截
---这么做看起来也很低能,为何不用/cast [target=mouseover,nodead,exists,harm] 拦截,经过长期JJC实践,当你正攻击一个目标A,法师B读条,如果用这个拦截宏打断,你会发现你的自动攻击目标还在A这里,冲锋也有这种病,原因是冲锋或拦截后自动开始攻击,所以,把宏换成现在这种格式,先把目标切换到要拦截的目标在拦截,一样用
#showtooltip 拦截
/target mouseover,nodead,exists,harm
/cast 拦截
/stopattack
---这个拦截打断宏目前没太大作用,这是我在2.4的时候跟法师单挑用的,作用是拦截法师停止自动攻击防止那一下打到冰甲中减速,刺耳反跑,这个宏在当时对法师作用非常明显,但这个畸形版本都是秒,操作性降低太多了
断筋宏
#showtooltip 断筋
/cast [target=mouseover,nodead,exists,harm][target=target,nodead,exists,harm] 断筋
/startattack
---还是mouseover
打断宏
#showtooltip 拳击
/cast [target=mouseover,nodead,exists,harm][target=target,nodead,exists,harm] 拳击
/cast 冲锋
#showtooltip 盾击
/cast [target=mouseover,nodead,exists,harm][target=target,nodead,exists,harm] 盾击
/stopcasting
/equipslot [noequipped:单手] 16 残酷角斗士的轻锤
/equipslot [noequipped:盾牌] 17 野蛮角斗士的墙盾
/cast 冲锋
---这俩宏后面都加入了个冲锋,因为目前我是玩防战PVP,还是快捷键惹的祸...不喜欢的可以去掉
盾反宏
#showtooltip 法术反射
/cast 法术反射
/cast [stance:3]战斗姿态
/stopcasting
/equipslot [noequipped:单手] 16 残酷角斗士的轻锤
/equipslot [noequipped:盾牌] 17 野蛮角斗士的墙盾
---以前cast在下面,自从无法一键盾反后放在哪都一样了
破胆宏
#showtooltip 破胆怒吼
/cast [target=mouseover,nodead,exists,harm][target=target,nodead,exists,harm] 破胆怒吼
---破胆宏效果也是很不错的,他的用法是破胆你鼠标指向的目标,如果没鼠标指向就破胆你当前目标,这个宏对有宝宝的职业或在JJC战场里对另外一个你不攻击的目标用的,破胆旁边的目标会造成你当前的目标恐惧而不是一打就开的昏迷
缴械宏
#showtooltip 缴械
/cast [target=mouseover,nodead,exists,harm][target=target,nodead,exists,harm] 缴械
英勇绑定乘胜
#showtooltip 英勇打击
/cast 英勇打击
/cast [nostance:2]乘胜追击
---没必要为乘胜追击单独设一个快捷键,所以绑定到其他技能里,绑定英勇是因为他俩不共CD
三大招宏
#showtooltip 反击风暴
/cast 反击风暴
/cast [nostance:1]战斗姿态
#showtooltip 盾墙
/cast 盾墙
/stopcasting
/cast [nostance:2]防御姿态
/equipslot [noequipped:单手] 16 残酷角斗士的轻锤
/equipslot [noequipped:盾牌] 17 野蛮角斗士的墙盾
#showtooltip 鲁莽
/cast 鲁莽
/cast [nostance:3]狂暴姿态
补充
/equipslot [noequipped:单手] 16 残酷角斗士的轻锤
/equipslot [noequipped:盾牌] 17 野蛮角斗士的墙盾
---如果是狂暴战换主手拿双手武器副手拿盾,请把noequipped:单手换成noequipped:双手
这所有宏都是我从网上搜罗来的,加以改编做成适合自己用的,那些技能绑定的太自动的宏我感觉并不太好,最起码不适合我,比如冲锋断筋宏,你手动完全可以做到自动宏的效果,有时太自动了也会影响发挥
总之,适合自己的才是最好的
6区森金冷风,还请高手指点更高端的PVP宏
另外自己30级暗夜小DZ作出一个影遁宏,
#showtooltip 影遁
/cast [nocombat,nostance:1]潜行;[nostealth]影遁
---首先如果不在战斗中且不在潜行中就施放潜行,如果在战斗中就施放影遁,这个宏也是要你按两次,目前没发现一键的....这个宏的主要目的是防止你进入潜行重复快速的按这个宏,导致按多了自己取消潜行了
---要点在nostance:1和nostealth 一个是判断是否在潜行,一种是判断是否在隐形,潜行和影遁都背判定为隐形,用nostance:1是判断是否在潜行姿态中,主要作用是与影遁区别开,有这个宏你可以放心的按多少次都没问题,当消失用
标签：PVP,有宏,发点
